Hướng dẫn cách sử dụng Logic Boolean trong Microsoft Excel

Nếu bạn đã từng bắt gặp từ “Boolean” nhưng không hoàn toàn chắc chắn ý nghĩa của nó, thì đây là hướng dẫn dành cho bạn! Từ định nghĩa các thuật ngữ chính đến các ví dụ dễ làm theo, đây là mọi thứ bạn cần biết về logic Boolean trong Microsoft Excel.

Xem thêm: Hướng dẫn cách sử dụng các phím chức năng trong Microsoft Excel

1. Logic Boolean: Các định nghĩa chính

Dưới đây là bốn thuật ngữ chính được sử dụng trong bài viết này và rất cần thiết để hiểu cách thức hoạt động của logic Boolean:

• Logic Boolean (Boolean logic): Phương pháp được sử dụng để đánh giá các điều kiện, trả về kết quả là ĐÚNG (TRUE) hoặc SAI (FALSE).

• Giá trị Boolean (Boolean values): Hai giá trị Boolean là ĐÚNG (TRUE) và SAI (FALSE). Khi được sử dụng trong công thức, TRUE tương đương với 1, và FALSE tương đương với 0.

• Hàm logic (Logical functions): Các hàm logic chính trong Excel cho phép bạn áp dụng logic Boolean là AND, OR, XOR, NOT, IF và các biến thể của chúng.

• Toán tử logic (Logical operators): Các ký hiệu toán học được sử dụng để so sánh các giá trị và trả về một giá trị Boolean. Các toán tử so sánh trong Excel là: = (bằng), > (lớn hơn), < (nhỏ hơn), >= (lớn hơn hoặc bằng), =< (nhỏ hơn hoặc bằng), và <> (không bằng).

2. Giá trị Boolean: ĐÚNG (TRUE) và SAI (FALSE)

Kết quả của logic Boolean luôn luôn là ĐÚNG (TRUE) nếu các điều kiện đã nêu được đáp ứng, hoặc SAI (FALSE) nếu chúng không được đáp ứng.

Ví dụ: gõ công thức sau:

=15=15

Vào một ô trong Excel và nhấn Enter sẽ trả về TRUE, vì giá trị trước toán tử logic bằng (=) giống với giá trị sau toán tử logic bằng. Nói cách khác, 15 bằng 15, vì vậy kết quả là ĐÚNG.

Mọi công thức trong Excel đều bắt đầu bằng ký hiệu bằng (=). Điều này không nên nhầm lẫn với toán tử logic bằng (=) được sử dụng giữa các điều kiện trong logic Boolean để so sánh sự bằng nhau.

Tương tự, trong ví dụ này, gõ:

=B2=B3

Trả về FALSE, vì giá trị trong ô B2 không bằng giá trị trong ô B3.

Mặc dù kết quả trong các ví dụ trên dường như là văn bản, nhưng các giá trị Boolean thực chất mang giá trị số. Cụ thể, TRUE = 1 và FALSE = 0. Bạn có thể kiểm tra điều này bằng cách sử dụng hàm SUM để cộng các ô chứa các giá trị Boolean này. Trong trường hợp này, gõ:

=A1+B1

Trả về 1, vì bạn đang cộng một giá trị TRUE (1) với một giá trị FALSE (0).

Hãy xem xét các giá trị Boolean hoạt động trong một tình huống thực tế.

Hãy tưởng tượng bạn đang theo dõi số lượng đơn hàng mà mỗi nhân viên đã giao trong khoảng thời gian bốn ngày. Mỗi nhân viên có 100 mặt hàng cần giao, và bạn muốn sử dụng logic Boolean để tìm hiểu xem họ đã hoàn thành tất cả hay chưa.

Để làm điều này, trong ô F2, gõ:

=B2+C2+D2+E2=100

Và nhấn Enter. Vì các giá trị trong ô B2, C2, D2 và E2 bằng 100 khi cộng lại, kết quả là TRUE.

Tuy nhiên, khi bạn chọn ô F2 và nhấp đúp vào tay cầm điền (fill handle) để áp dụng công thức cho các ô còn lại, bạn có thể thấy rằng các giá trị Boolean trong ô F3 và F4 là FALSE, vì tổng số mặt hàng đã giao cho mỗi nhân viên đó không bằng 100.

Để hình dung các giá trị Boolean rõ ràng hơn, bạn có thể biến chúng thành ô đánh dấu (checkboxes), trong đó TRUE tạo ra ô được đánh dấu, và FALSE tạo ra ô không được đánh dấu. Chọn tất cả các ô chứa giá trị Boolean, và trong tab Insert (Chèn) trên dải băng (ribbon), nhấp vào “Checkbox” (Ô đánh dấu).

Bây giờ, nếu bạn cập nhật các số liệu sao cho tổng số của nhân viên B bằng 100, giá trị Boolean chuyển thành TRUE, và do đó, ô đánh dấu được chọn.

Mặt khác, với kiến thức rằng các ô đánh dấu được chọn tương đương với 1, bạn có thể sử dụng chúng để theo dõi tiến độ công việc. Ở đây, gõ công thức:

=B2*C2*D2=1

vào ô E2, sẽ trả về TRUE nếu tất cả các ô đánh dấu được chọn (1*1*1=1), hoặc FALSE nếu bất kỳ ô đánh dấu nào không được chọn (ví dụ: 1*0*1=0).

Sau đó, bạn có thể tự biến những giá trị Boolean này thành các ô đánh dấu nếu muốn.

3. Các hàm Logic: AND, OR, XOR, NOT, và IF

Cho đến nay, tôi đã chỉ cho bạn cách logic Boolean hoạt động để kiểm tra xem một thứ có bằng thứ khác hay không. Tuy nhiên, bạn có thể sử dụng các hàm logic của Excel để kiểm tra nhiều hơn một điều kiện, kiểm tra xem một thứ có không bằng thứ khác hay không, hoặc trả về các giá trị thay thế cho TRUE và FALSE.

AND, OR, và XOR: Kiểm tra nhiều điều kiện:

Đúng như tên gọi, các hàm logic AND,OR, và XOR đánh giá nhiều hơn một điều kiện bằng cách sử dụng logic Boolean để trả về kết quả là TRUE hoặc FALSE:

• Ví dụ về AND:

Trong ví dụ này, hàm AND trả về TRUE cho nhân viên A và D vì cả hai điều kiện (cột Induction – Nhập môn và Probation – Thử việc đều chứa “Y”) được đáp ứng.

=AND(B2="Y",C2="Y")

Lưu ý: Bất kỳ giá trị văn bản nào được sử dụng trong công thức logic, dù là trong kiểm tra logic hay giá trị trả về, đều phải được đặt trong dấu ngoặc kép đôi (""). Các trường hợp ngoại lệ duy nhất là TRUE và FALSE, vì chúng được coi là giá trị Boolean chứ không phải giá trị văn bản. Giá trị số không cần dấu ngoặc kép đôi.

• Ví dụ về OR:

Ở đây, hàm OR trả về TRUE cho nhân viên B trong ô D2, bởi vì ngay cả khi giá trị trong ô B3 không bằng “Gold,” giá trị trong ô C3 bằng “Senior,” nên một trong các điều kiện được đáp ứng. Mặt khác, nhân viên A, C và D không đáp ứng cả hai tiêu chí này, vì vậy kết quả của họ là FALSE.

=OR(B3="Gold",C3="Senior")

• Ví dụ về XOR:

Hàm XOR được sử dụng tốt nhất khi có sự lựa chọn giữa A hoặc B, vì nó cho phép bạn theo dõi xem không chọn cái nào, chọn cả hai, hay chỉ một tùy chọn được chọn.

Ở đây, nhân viên có thể chọn hoặc kế hoạch chăm sóc sức khỏe A hoặc kế hoạch chăm sóc sức khỏe B. Nếu họ chỉ đánh dấu một trong các tùy chọn này, hàm XOR trả về TRUE. Tuy nhiên, nếu họ không đánh dấu cái nào hoặc đánh dấu cả hai tùy chọn, hàm trả về FALSE.

=XOR(B2=TRUE,C2=TRUE)

Bạn cũng có thể lồng các hàm logic này để tạo ra các điều kiện cụ thể hơn.

• Ví dụ về lồng hàm:

Trong ví dụ này, logic Boolean trả về TRUE nếu (1) giá trị trong cột B là hoặc “Sun” hoặc “Overcast,” và (2) giá trị trong cột C là “Y.”

=AND(OR(B3="Sun",B3="Overcast"),C3="Y")

Các hàm AND, OR và XOR cho phép lên đến 255 điều kiện.

NOT: Đảo ngược Logic Boolean:

Hàm NOT trong Excel về cơ bản đảo ngược logic Boolean bằng cách trả về TRUE nếu các điều kiện không được đáp ứng, hoặc FALSE nếu các điều kiện được đáp ứng.

• Ví dụ về NOT:

Trong ví dụ này, hàm NOT trả về TRUE nếu các giá trị trong cột B không khớp với các giá trị trong cột C:

=NOT(B2=C2)

Cũng như các ví dụ trên, bạn có thể lồng các hàm logic khác bên trong một công thức NOT để đánh giá nhiều điều kiện. Ở đây, gõ:

=NOT(AND(B2="Good",C2="Good"))

trả về TRUE nếu xếp hạng của nhà hàng ở U.S. và U.K. không đồng thời là “Good.”

Mặt khác, sử dụng logic tương tự với NOT và OR, công thức này trả về TRUE nếu cả xếp hạng ở U.S. và U.K. đều không là “Good.”

=NOT(OR(B2="Good",C2="Good"))

4. IF: Trả về giá trị tùy chỉnh

Trong khi logic Boolean chủ yếu trả về các giá trị Boolean (TRUE hoặc FALSE), bạn có thể buộc Excel trả về các giá trị thay thế bằng cách sử dụng hàm IF.

Cú pháp cho hàm IF như sau:

=IF(a, b, c)

Trong đó:

• a là phép kiểm tra logic Boolean, có thể được đánh giá là TRUE hoặc FALSE,

• b là giá trị trả về thay vì TRUE, và

• c là giá trị trả về thay vì FALSE.

Đối số a là bắt buộc, và cả hai hoặc một trong hai đối số b và/hoặc c cũng phải được cung cấp. Nếu bạn bỏ qua đối số b hoặc đối số c, công thức sẽ trả về TRUE hoặc FALSE ở vị trí của nó.

Để trả về một ô trống thay vì giá trị cho TRUE hoặc FALSE, hãy gõ "" (hai dấu ngoặc kép đôi) cho đối số b hoặc c.

Ví dụ về IF:

Giả sử bạn đang tuyển dụng nhân viên cho doanh nghiệp của mình. Cụ thể, bạn muốn phỏng vấn các ứng viên đáp ứng các tiêu chí sau:

• Họ có chứng chỉ bạc hoặc vàng,

• Họ đã cung cấp người tham chiếu trong sơ yếu lý lịch, và

• Họ có thể đi lại.

Nếu họ đáp ứng các tiêu chí trên, bạn muốn trả về “Interview” (Phỏng vấn) trong cột trạng thái. Tuy nhiên, nếu họ không đáp ứng, bạn muốn trả về “Send rejection” (Gửi thư từ chối).

Để làm điều này, trong ô E2, gõ:

=IF(AND(OR(B2="Silver",B2="Gold"),C2="Y",D2="Y"), "Interview", "Send rejection")

Đây là cách công thức này hoạt động:

• Hàm IF sử dụng logic Boolean và cho phép bạn trả về “Interview” thay vì TRUE, và “Send rejection” thay vì FALSE.

• Hàm OR kiểm tra xem giá trị trong cột B là hoặc “Silver” hoặc “Gold.”

• Hàm AND kiểm tra xem, ngoài việc có chứng chỉ bạc hoặc vàng (cột B), ứng viên có cung cấp người tham chiếu (cột C) và có thể đi lại (cột D) hay không.

Để đánh giá nhiều điều kiện và trả về kết quả cho điều kiện đầu tiên trả về TRUE, hãy sử dụng hàm IFS.

5. Toán tử Logic: So sánh các giá trị trong Logic Boolean

Nếu bạn đang sử dụng logic Boolean để đánh giá các giá trị số, bạn không nhất thiết chỉ sử dụng dấu bằng. Thật vậy, bạn có thể kiểm tra xem một giá trị có lớn hơn, nhỏ hơn, lớn hơn hoặc bằng, nhỏ hơn hoặc bằng, hoặc không bằng một giá trị khác hay không.

• Ví dụ với số:

Trong ví dụ này, nếu một học sinh đạt điểm 75 trở lên, bạn muốn trả về “Pass” (Đạt) trong cột C. Nếu không, bạn muốn trả về “Fail” (Trượt).

Công thức để đạt được điều này là:

=IF(B2>=75, "Pass", "Fail")

• Ví dụ với ngày tháng:

Bạn có thể sử dụng logic Boolean và các toán tử logic với ngày tháng, trong đó ký hiệu “lớn hơn” (>) có nghĩa là “sau ngày”, ký hiệu “nhỏ hơn” (<) có nghĩa là “trước ngày”.

Ở đây, gõ:

=IF(B2>TODAY(), "Coming soon", "Available now")

Trả về “Coming soon” (Sắp ra mắt) nếu ngày trong cột B sau ngày hôm nay, hoặc “Available now” (Có sẵn ngay) nếu ngày trong cột B trước ngày hôm nay.

Để ngày tháng hoạt động như mong đợi trong công thức Excel, hãy đảm bảo giá trị được đặt thành định dạng ngày tháng được nhận dạng trong nhóm Number (Số) của tab Home (Trang chủ) trên dải băng (ribbon).

Nếu bạn đang bao gồm ngày tháng trực tiếp trong công thức (thay vì tham chiếu đến một ô chứa ngày), hãy sử dụng hàm DATEVALUE, với ngày tháng được đặt trong dấu ngoặc kép đôi, sau đó đặt trong dấu ngoặc đơn:

=IF(B2<DATEVALUE("2025/12/25"), "Yes", "No")

Bây giờ bạn đã biết cách áp dụng logic Boolean vào các số liệu của mình trong Microsoft Excel, hãy nâng kiến thức này lên một bước nữa bằng cách tận dụng tối đa sức mạnh của các hàm COUNTIF, SUMIF và AVERAGEIF để đếm, tính tổng và tính trung bình các ô khớp với các tiêu chí nhất định.