Hướng dẫn cách đặt lại Windows Update trên Windows 11

Trên Windows 11, dịch vụ Windows Update cho phép hệ thống nhận các bản cập nhật mới nhất từ Microsoft để khắc phục lỗi, vá lỗ hổng bảo mật và triển khai các driver mới hơn. Ngoài ra, đây còn là dịch vụ chính để tải về các bản cập nhật tính năng và các bản build Insider Preview.

Tuy nhiên, Windows Update không phải lúc nào cũng hoàn hảo, và đôi khi máy tính có thể gặp khó khăn trong việc tải xuống hoặc cài đặt các bản cập nhật do các lỗi cụ thể, hệ thống không kết nối được với dịch vụ trực tuyến, cùng nhiều vấn đề khác.

Thông thường, các vấn đề xảy ra khi cơ chế cập nhật bị dừng hoạt động, Windows 11 gặp vấn đề với bộ nhớ cache cập nhật, hoặc hệ thống phát hiện các file cài đặt bị hỏng. Nếu gặp sự cố, bạn có thể đặt lại Windows Update trên Windows 11 để khắc phục hầu hết các vấn đề bằng cách sử dụng tính năng Troubleshoot, áp dụng cập nhật thủ công, sửa chữa các file hệ thống bị hỏng, hoặc đặt lại các thành phần của Windows Update. Trong hướng dẫn này, bạn sẽ học cách đặt lại các thành phần Windows Update trên Windows 11.

Xem thêm: Hướng dẫn cách kích hoạt các tính năng mới cho bản cập nhật Windows 11

1. Đặt lại Windows Update bằng tính năng Troubleshoot trên Windows 11

Để đặt lại Windows Update bằng tính năng Troubleshoot trên Windows 11, hãy làm theo các bước sau:

1. Mở ứng dụng Settings trên Windows 11.

2. Nhấp vào System.

3. Nhấp vào trang Troubleshoot.

4. Nhấp vào cài đặt Other troubleshooters.

5. Trong phần “Most frequent”, nhấp vào nút Run cho cài đặt “Windows Update”.

6. Tiếp tục làm theo các hướng dẫn trên màn hình bằng ứng dụng Get Help (nếu áp dụng).

Sau khi máy tính khởi động lại, lần tiếp theo bạn thử cập nhật Windows 11, hệ thống sẽ hoạt động như mong đợi.

2. Khắc phục lỗi Windows Update bằng cách cài đặt cập nhật thủ công trên Windows 11

Nếu bạn gặp vấn đề với Windows Update, việc cài đặt bản cập nhật mới nhất có sẵn có thể tự động giải quyết vấn đề. Ngoài ra, các bản cập nhật tích lũy hiện nay đã kết hợp “Servicing Stack Update” (SSU), một bản cập nhật được thiết kế để cải thiện và khắc phục các vấn đề nhằm làm cho Windows Update đáng tin cậy hơn.

Để cài đặt cập nhật thủ công nhằm khắc phục sự cố Windows Update trên Windows 11, hãy làm theo các bước sau:

1. Mở trang web lịch sử cập nhật Windows 11.

2. Chọn bản cập nhật mới nhất của Windows 11 từ khung bên trái (và ghi chú số “KB” của bản cập nhật).

Mẹo nhanh: Bạn có thể kiểm tra phiên bản hiện tại tại Settings > System > About và trong phần “Windows Specifications”, xác nhận thông tin phiên bản.

3. Mở trang web Microsoft Update Catalog.

4. Tìm kiếm số knowledge base (KB) của bản cập nhật mới nhất (dành cho x64).

5. Nhấp vào nút Download cho bản cập nhật Windows 11 mới nhất.

6. Nhấp vào liên kết tải xuống “.msu”, sau đó lưu file vào thiết bị.

Ghi chú nhanh: Bạn phải tải xuống cả hai gói và cài đặt chúng theo đúng thứ tự.

7. Nhấp đúp vào các gói (một gói một lần) để cài đặt chúng và khắc phục sự cố Windows Update.

8. Khởi động lại máy tính.

Sau khi hoàn thành các bước, thiết bị sẽ áp dụng bản cập nhật mới nhất. Quá trình cài đặt cũng sẽ khắc phục mọi vấn đề liên quan đến dịch vụ Windows Update.

3. Khắc phục Windows Update bằng cách sửa các tệp bị hỏng trên Windows 11

Dịch vụ Windows Update có thể bị lỗi do các tệp hệ thống bị hỏng. Nếu đây là trường hợp xảy ra, bạn có thể sử dụng công cụ Deployment Image Servicing and Management (DISM) để đảm bảo rằng hình ảnh hệ thống cục bộ của Windows 11 đang ở trạng thái tốt, sau đó dùng công cụ System File Checker (SFC) để khắc phục các sự cố trên Windows Update bằng cách sử dụng các tệp từ hình ảnh hệ thống cục bộ.

Để sửa chữa các tệp hệ thống nhằm khắc phục sự cố cập nhật trên Windows 11, hãy làm theo các bước sau:

1. Mở Start (Bắt đầu).

2. Tìm kiếm Command Prompt, nhấp chuột phải vào kết quả hàng đầu và chọn tùy chọn Run as administrator (Chạy với quyền quản trị).

3. Nhập lệnh DISM sau để sửa chữa các tệp hệ thống bị hỏng và nhấn Enter:

dism.exe /Online /Cleanup-image /Restorehealth

4. Nhập lệnh SFC sau để sửa chữa các tệp hệ thống và nhấn Enter:

sfc /scannow

Sau khi hoàn thành các bước, các thành phần của Windows Update sẽ hoạt động trở lại và bạn có thể kiểm tra các bản cập nhật một lần nữa để xác minh.

4. Đặt lại (Reset) Windows Update bằng Command Prompt trên Windows 11

Ngoài ra, bạn có thể đặt lại tất cả các thành phần của Windows Update bằng các lệnh để khắc phục các sự cố phổ biến nhất. Thông thường, đây là lựa chọn tốt nhất để giải quyết các vấn đề với cơ chế cập nhật trên Windows 11.

Để đặt lại Windows Update thủ công từ Command Prompt trên Windows 11, hãy làm theo các bước sau:

1. Mở Start (Bắt đầu).

2. Tìm kiếm Command Prompt, nhấp chuột phải vào kết quả hàng đầu và chọn tùy chọn Run as administrator (Chạy với quyền quản trị).

3. Nhập các lệnh sau để dừng Background Intelligent Transfer Service (BITS), Windows Update service và Cryptographic service, sau đó nhấn Enter sau mỗi dòng:

net stop bits
net stop wuauserv
net stop appidsvc
net stop cryptsvc

Mẹo nhanh: Bạn có thể cần chạy lại lệnh nhiều lần cho đến khi thấy thông báo rằng dịch vụ đã dừng thành công.

4. Nhập lệnh sau để xóa tất cả các tệp “qmgr*.dat” do BITS tạo ra khỏi máy tính của bạn và nhấn Enter:

Del "%ALLUSERSPROFILE%\Application Data\Microsoft\Network\Downloader\*.*"

5. Nhập “Y” để xác nhận việc xóa.

6. Nhập các lệnh sau để xóa bộ nhớ đệm (cache) của Windows Update, cho phép Windows 11 tải lại các bản cập nhật thay vì sử dụng các tệp đã tải xuống trên hệ thống có thể bị hỏng, và nhấn Enter sau mỗi dòng:

rmdir %systemroot%\SoftwareDistribution /S /Q
rmdir %systemroot%\system32\catroot2 /S /Q

Mẹo nhanh: Chúng ta sử dụng lệnh xóa thư mục rmdir với tùy chọn /S để xóa thư mục được chỉ định và tất cả các thư mục con bên trong thư mục chính, và tùy chọn /Q xóa thư mục một cách “im lặng” mà không cần xác nhận. Nếu bạn nhận được thông báo “The process cannot access the file because it is being used by another process” (Tiến trình không thể truy cập tệp vì nó đang được tiến trình khác sử dụng), hãy lặp lại bước 1 và thử lại, vì một trong các dịch vụ có thể đã khởi động lại bất ngờ.

7. Nhập các lệnh sau để đặt lại mô tả bảo mật (security descriptor) của dịch vụ BITS và Windows Update về mặc định, và nhấn Enter sau mỗi dòng:

sc.exe sdset bits D:(A;;CCLCSWRPWPDTLOCRRC;;;SY)(A;;CCDCLCSWRPWPDTLOCRSDRCWDWO;;;BA)(A;;CCLCSWLOCRRC;;;AU)(A;;CCLCSWRPWPDTLOCRRC;;;PU)
sc.exe sdset wuauserv D:(A;;CCLCSWRPWPDTLOCRRC;;;SY)(A;;CCDCLCSWRPWPDTLOCRSDRCWDWO;;;BA)(A;;CCLCSWLOCRRC;;;AU)(A;;CCLCSWRPWPDTLOCRRC;;;PU)

8. Nhập lệnh sau để chuyển đến thư mục System32 và nhấn Enter:

cd /d %windir%\system32

9. Nhập các lệnh sau để đăng ký tất cả các tệp DLL tương ứng của BITS và Windows Update vào Registry, và nhấn Enter sau mỗi dòng:

regsvr32.exe /s atl.dll
regsvr32.exe /s urlmon.dll
regsvr32.exe /s mshtml.dll
regsvr32.exe /s shdocvw.dll
regsvr32.exe /s browseui.dll
regsvr32.exe /s jscript.dll
regsvr32.exe /s vbscript.dll
regsvr32.exe /s scrrun.dll
regsvr32.exe /s msxml.dll
regsvr32.exe /s msxml3.dll
regsvr32.exe /s msxml6.dll
regsvr32.exe /s actxprxy.dll
regsvr32.exe /s softpub.dll
regsvr32.exe /s wintrust.dll
regsvr32.exe /s dssenh.dll
regsvr32.exe /s rsaenh.dll
regsvr32.exe /s gpkcsp.dll
regsvr32.exe /s sccbase.dll
regsvr32.exe /s slbcsp.dll
regsvr32.exe /s cryptdlg.dll
regsvr32.exe /s oleaut32.dll
regsvr32.exe /s ole32.dll
regsvr32.exe /s shell32.dll
regsvr32.exe /s initpki.dll
regsvr32.exe /s wuapi.dll
regsvr32.exe /s wuaueng.dll
regsvr32.exe /s wuaueng1.dll
regsvr32.exe /s wucltui.dll
regsvr32.exe /s wups.dll
regsvr32.exe /s wups2.dll
regsvr32.exe /s wuweb.dll
regsvr32.exe /s qmgr.dll
regsvr32.exe /s qmgrprxy.dll
regsvr32.exe /s wucltux.dll
regsvr32.exe /s muweb.dll
regsvr32.exe /s wuwebv.dll

Lưu ý nhanh: Lệnh regsvr32 giúp đăng ký các tệp “.DLL” làm thành phần lệnh trong Registry, và chúng ta sử dụng tùy chọn /S để chỉ định công cụ chạy lệnh một cách im lặng mà không hiển thị thêm thông báo.

10. Nhập các lệnh sau để đặt lại cấu hình mạng có thể là nguyên nhân của vấn đề (nhưng chưa khởi động lại máy tính), và nhấn Enter sau mỗi dòng:

netsh winsock reset
netsh winsock reset proxy

11. Nhập các lệnh sau để khởi động lại dịch vụ BITS, Windows Update và Cryptographic, và nhấn Enter sau mỗi dòng:

net start bits
net start wuauserv
net start appidsvc
net start cryptsvc

12. Khởi động lại máy tính.

Sau khi bạn hoàn thành các bước này, Windows Update sẽ được đặt lại và sẽ hoạt động trở lại trên Windows 11.

Ngoài ra, bạn cũng có thể sao chép và dán tập lệnh (script) này, lưu nó dưới dạng tệp “.bat” bằng Notepad, sau đó chạy nó với quyền quản trị để quá trình này được tự động hóa hơn:

@echo off
echo Stopping services...
net stop bits
net stop wuauserv
net stop appidsvc
net stop cryptsvc

echo Deleting BITS cache...
del /f /q "%ALLUSERSPROFILE%\Application Data\Microsoft\Network\Downloader\*.*"

echo Clearing Windows Update cache...
rmdir %systemroot%\SoftwareDistribution /S /Q
rmdir %systemroot%\system32\catroot2 /S /Q

echo Resetting service security descriptors...
sc.exe sdset bits D:(A;;CCLCSWRPWPDTLOCRRC;;;SY)(A;;CCDCLCSWRPWPDTLOCRSDRCWDWO;;;BA)(A;;CCLCSWLOCRRC;;;AU)(A;;CCLCSWRPWPDTLOCRRC;;;PU)
sc.exe sdset wuauserv D:(A;;CCLCSWRPWPDTLOCRRC;;;SY)(A;;CCDCLCSWRPWPDTLOCRSDRCWDWO;;;BA)(A;;CCLCSWLOCRRC;;;AU)(A;;CCLCSWRPWPDTLOCRRC;;;PU)

echo Registering DLLs...
cd /d %windir%\system32
for %%i in (
atl.dll urlmon.dll mshtml.dll shdocvw.dll browseui.dll jscript.dll vbscript.dll
scrrun.dll msxml.dll msxml3.dll msxml6.dll actxprxy.dll softpub.dll wintrust.dll
dssenh.dll rsaenh.dll gpkcsp.dll sccbase.dll slbcsp.dll cryptdlg.dll oleaut32.dll
ole32.dll shell32.dll initpki.dll wuapi.dll wuaueng.dll wuaueng1.dll wucltui.dll
wups.dll wups2.dll wuweb.dll qmgr.dll qmgrprxy.dll wucltux.dll muweb.dll wuwebv.dll
) do regsvr32.exe /s %%i

echo Resetting network stack...
netsh winsock reset
netsh winsock reset proxy

echo Starting services...
net start bits
net start wuauserv
net start appidsvc
net start cryptsvc

echo.
echo Done. Restart the computer to complete the process.
pause

Sau khi bạn chạy tập lệnh và khởi động lại máy tính, bạn có thể kiểm tra các bản cập nhật thông qua trang cài đặt “Windows Update”.

Nếu bạn nhận được lỗi “0x80248007” khi tải xuống bản cập nhật tích lũy (cumulative) hoặc bản cập nhật tính năng (feature update), bạn sẽ cần đợi một thời gian (lên đến 24 giờ), và lỗi sẽ tự động biến mất.

5. Câu hỏi thường gặp (FAQs)

Dưới đây là danh sách các câu hỏi thường gặp (FAQs) và câu trả lời về việc đặt lại Windows Update.

• Nguyên nhân nào khiến Windows Update ngừng hoạt động trên Windows 11?

Windows Update có thể thất bại khi các dịch vụ cập nhật cốt lõi dừng chạy, bộ nhớ cache cập nhật bị hỏng, hoặc các file hệ thống cần thiết cho việc cài đặt bị hư hại. Các vấn đề mạng, sự cố máy chủ Windows Update, và xung đột driver cũng có thể ngăn chặn việc tải xuống hoặc cài đặt cập nhật đúng cách.

• Khi nào tôi nên đặt lại các thành phần Windows Update?

Bạn nên đặt lại các thành phần khi các bản cập nhật liên tục thất bại trong việc tải xuống, cài đặt hoặc hoàn tất. Khi cập nhật bị kẹt ở một tỷ lệ phần trăm nhất định, hoặc khi bạn nhận được các mã lỗi dai dẳng ngay cả sau khi sử dụng Troubleshooter. Việc đặt lại giúp sửa chữa các thư mục cache bị hỏng, đăng ký lại dịch vụ và khôi phục cấu hình mặc định.

• Windows Update Troubleshooter có khắc phục được hầu hết các vấn đề cập nhật không?

Troubleshooter có thể sửa chữa các vấn đề phổ biến như dịch vụ bị kẹt, cache bị hỏng hoặc thành phần bị cấu hình sai. Tuy nhiên, nó không khắc phục được sự hỏng hóc sâu hơn trong file hệ thống hoặc cơ sở hạ tầng Windows Update bị hư hại. Trong các trường hợp phức tạp, việc sử dụng DISM, SFC hoặc đặt lại toàn bộ các thành phần Windows Update sẽ hiệu quả hơn.

• Việc cài đặt cập nhật thủ công có khắc phục được lỗi Windows Update không?

Có. Việc tải xuống và cài đặt thủ công bản cập nhật tích lũy mới nhất thường giải quyết các vấn đề đang chặn Windows Update. Các bản cập nhật tích lũy bao gồm các bản sửa Servicing Stack có thể tự động khôi phục chức năng cập nhật.

• Việc xóa thư mục SoftwareDistribution và catroot2 có an toàn không?

Có. Những thư mục này chứa các file cập nhật tạm thời. Việc xóa chúng buộc Windows phải tải xuống nội dung mới và thường giải quyết các vấn đề liên quan đến hỏng hóc. Bạn phải dừng tất cả các dịch vụ liên quan đến cập nhật trước khi xóa các thư mục này để tránh lỗi file đang được sử dụng.

• Việc chạy DISM và SFC làm gì khi khắc phục vấn đề cập nhật?

DISM sửa chữa hình ảnh hệ điều hành cơ bản, đảm bảo hệ thống có các file nguồn lành mạnh. SFC kiểm tra và sửa chữa các file hệ thống bị hỏng hoặc thiếu bằng cách sử dụng hình ảnh đã được sửa. Việc chạy cả hai công cụ có thể giải quyết các thất bại cập nhật do hỏng hóc ở cấp độ hệ thống.

• Tại sao nên đặt lại dịch vụ Windows Update từ Command Prompt?

Việc đặt lại từ Command Prompt cho phép bạn dừng hoàn toàn các dịch vụ cập nhật, xóa cache cập nhật, đặt lại mô tả bảo mật, đăng ký lại các DLL và xây dựng lại stack mạng. Phương pháp này triệt để hơn Troubleshooter và khắc phục các vấn đề cứng đầu mà các công cụ tự động không giải quyết được.

• Việc đặt lại Windows Update có xóa file cá nhân hoặc ứng dụng của tôi không?

Không. Việc đặt lại chỉ ảnh hưởng đến các thành phần liên quan đến cập nhật và thư mục cache. Tài liệu, ứng dụng và cài đặt của bạn vẫn nguyên vẹn.

• Tôi nên làm gì nếu tiếp tục nhận được mã lỗi Windows Update như 0x8007000d hoặc 0x800f0922?

Những mã này thường xuất hiện khi cache cập nhật bị hỏng hoặc file hệ thống gặp vấn đề. Việc chạy DISM, SFC, cài đặt cập nhật thủ công hoặc đặt lại toàn bộ thành phần cập nhật thường giải quyết chúng. Nếu lỗi vẫn còn, bước tiếp theo là thực hiện cài đặt sửa chữa bằng file ISO.

• Tôi nên chờ bao lâu nếu Windows Update hiển thị lỗi 0x80248007?

Lỗi này xảy ra khi dịch vụ Windows Update không thể truy cập metadata cần thiết từ máy chủ của Microsoft. Vấn đề thường tự khắc phục trong vòng vài giờ. Microsoft khuyến nghị chờ tối đa 24 giờ trước khi thử lại.

• Tôi có thể sử dụng cài đặt sửa chữa nếu không có cách nào khác khắc phục Windows Update không?

Có. Cài đặt sửa chữa (nâng cấp tại chỗ) sẽ cài đặt lại Windows 11 lên hệ thống hiện tại mà không xóa ứng dụng hoặc file. Nó thay thế tất cả các thành phần và dịch vụ hệ thống, là một trong những cách đáng tin cậy nhất để giải quyết các vấn đề cập nhật dai dẳng dù đã đặt lại và sửa chữa.