Ngừng viết các công thức IF lồng nhau và IFS trong Excel – Hãy dùng SWITCH thay thế

Các công thức Excel lộn xộn không chỉ xấu mắt – chúng còn khó bảo trì hơn rất nhiều. Mỗi lần lặp lại tham chiếu ô và dấu ngoặc ngoèo ngoẹo đều khiến công việc của bạn trở nên khó kiểm tra, khó chỉnh sửa và khó chia sẻ. Đó chính là lý do bạn nên sử dụng hàm SWITCH thay thế. Nó biến đống hỗn độn ấy thành một công thức sạch sẽ hơn, nhanh hơn và dễ hiểu hơn rất nhiều.

Xem thêm: Hướng dẫn cách cài đặt Zorin OS để chuyển đổi từ Windows 10

1. Công thức IF lồng nhau: Cơn ác mộng về cấu trúc

Công thức IF lồng nhau chính là những con búp bê Nga Matryoshka trong Microsoft Excel. Bạn bắt đầu với một câu lệnh IF đơn giản, rồi muốn thêm điều kiện thứ hai. Sau đó là điều kiện thứ ba. Bỗng nhiên, bạn đã lồng ghép hàng tầng lớp – hiện tượng được gọi là nesting.

Giả sử bạn đang sử dụng bảng Excel này để theo dõi tiến độ dự án.

Công thức bạn nhập để xác định trạng thái dựa trên số giai đoạn hoàn thành sẽ trông như thế này:

=IF([@Completed]=0,"Pending",IF([@Completed]=1,"Active",IF([@Completed]=2,"Active",IF([@Completed]=3,"Closed","Error"))))

Công thức này gặp vấn đề chủ yếu vì hai lý do:

• Mệt mỏi với dấu ngoặc: Mỗi lần mở một hàm IF, bạn phải đóng nó ở cuối cùng. Trong các bảng tính phức tạp, bạn thường thấy mình đang nhìn chằm chằm vào một chuỗi )))), tự hỏi liệu có thiếu dấu ngoặc nào không.
• Độ phức tạp trực quan: Để hiểu điều gì xảy ra khi cột Completed hiển thị giá trị 3, bộ não của bạn phải nhảy qua hai câu lệnh IF khác trước đã.

Khi sử dụng IF lồng nhau, bạn đang xây dựng một tháp logic dễ đổ vỡ. Chỉ một dấu phẩy sai vị trí là toàn bộ công thức sụp đổ.

2. Hàm IFS: Cơn ác mộng về sự dư thừa

Khi Microsoft giới thiệu hàm IFS trong Excel, mục tiêu là giải quyết cơn ác mộng dấu ngoặc mà mình vừa đề cập ở trên. Nó đã thành công trong việc làm phẳng cấu trúc, cho phép bạn liệt kê các điều kiện lần lượt mà không cần lồng ghép.

Áp dụng hàm này vào cùng bảng dữ liệu, bạn sẽ nhập:

=IFS([@Completed]=0,"Pending",[@Completed]=1,"Active",[@Completed]=2,"Active",[@Completed]=3,"Closed")

Mặc dù IFS là bước cải thiện so với việc lồng ghép, nó lại mang đến những vấn đề mới:

• Sự dư thừa: Hãy chú ý bạn phải nhập (hoặc click) tên cột tham chiếu bao nhiêu lần trong công thức, một lần cho mỗi kiểm tra logic. Điều này tạo ra những công thức dài dòng gấp đôi mức cần thiết và khó bảo trì hơn.
• Không có đối số “else” mặc định: Khác với hàm IF gốc, IFS không có đối số cuối cùng kiểu “nếu tất cả đều thất bại”. Kết quả là nếu dữ liệu không khớp bất kỳ tiêu chí nào, công thức sẽ trả về lỗi #N/A. Để khắc phục, bạn có thể thêm một câu lệnh TRUE ở cuối, nhưng điều này chỉ làm tăng thêm sự lộn xộn cho công thức.

Tóm lại, IFS giải quyết được cơn ác mộng dấu ngoặc, nhưng không loại bỏ được sự rối rắm.

3. Giải pháp: Hàm SWITCH

Hàm SWITCH cho phép bạn định nghĩa các quy tắc trong một danh sách sạch sẽ, biến công thức của bạn từ một phép tính phức tạp thành một bản dịch đơn giản dễ hiểu.

Cú pháp hàm SWITCH

Hàm SWITCH trong Excel có cú pháp logic rõ ràng:

=SWITCH(target,value1,result1,[value2,result2],...,[default])

Trong đó:

• target là giá trị hoặc tham chiếu ô cần so sánh với value1, value2, value3, v.v.
• value1 là giá trị đầu tiên sẽ được so sánh với target.
• result1 là giá trị trả về khi value1 khớp với target.
• value2,result2 là cặp giá trị-kết quả thứ hai, tối đa lên đến 126 cặp.
• default là đối số duy nhất đặt sau cặp giá trị-kết quả cuối cùng, đại diện cho giá trị “else” (mạng an toàn) trả về nếu không có khớp nào trong các đối số value.

Các đối số result và else phải đặt trong dấu ngoặc kép nếu chúng là chuỗi văn bản.

SWITCH hoạt động thực tế

Dưới đây là công thức bạn có thể sử dụng trong cột Status của bảng theo dõi tiến độ dự án:

=SWITCH([@Completed],0,"Pending",1,"Active",2,"Active",3,"Closed","Unknown")

Đây là lý do tại sao SWITCH là lựa chọn tốt hơn trong trường hợp này:

• Chỉ tham chiếu một lần: Bạn chỉ cần tham chiếu đến cột Completed một lần duy nhất. Trong bảng tính lớn, việc giảm nhiều tham chiếu xuống còn một giúp công thức gọn gàng hơn đáng kể, khó lỗi hơn và dễ chỉnh sửa hơn.
• Dễ đọc: Vì không có tham chiếu lặp lại, bạn có thể đọc công thức như tiếng Anh thông thường: “Xem cột Completed; nếu là 0 thì Pending; nếu là 1 thì Active…” và tiếp tục như vậy.
• Mạng an toàn tích hợp: Nếu ai đó nhập số không hợp lệ vào cột Completed, SWITCH sẽ bắt lỗi bằng đối số “else” ở cuối (“Unknown”).

Bằng cách sử dụng SWITCH, bạn không còn phải vật lộn với cú pháp phức tạp nữa mà bắt đầu viết những công thức thực sự dễ hiểu và hợp lý.

4. Mẹo SWITCH(TRUE): Chiêu cao thủ

Một chỉ trích phổ biến đối với hàm SWITCH trong Excel là nó chỉ xử lý các khớp chính xác, ví dụ như chuyển số 1 thành từ “Active”. Nếu bạn muốn dùng dấu lớn hơn hoặc nhỏ hơn, hầu hết mọi người nghĩ rằng phải quay lại với logic rối rắm của IF hoặc IFS.

Tuy nhiên, bạn hoàn toàn có thể dùng SWITCH cho các khoảng giá trị bằng một mẹo thông minh: bắt đầu công thức bằng TRUE:

=SWITCH(TRUE,[@Completed]=0,"Pending",[@Completed]<=2,"Active",[@Completed]=3,"Closed","Error")

Khi đặt đối số đầu tiên là TRUE, bạn đang bảo Excel tiếp tục duyệt qua công thức cho đến khi tìm thấy biểu thức nào đúng. Nhờ đó, bạn có thể gom cả 1 và 2 vào cùng một điều kiện để trả về “Active” chỉ trong một đối số.

Lý do nữa khiến mẹo này thay đổi cuộc chơi là bạn có được sự linh hoạt toán học của câu lệnh IF trong khi vẫn giữ cấu trúc danh sách tuyến tính sạch sẽ của SWITCH.

Sự đánh đổi “chỉ tham chiếu một lần”

Lưu ý nhỏ: việc dùng mẹo TRUE sẽ phần nào làm giảm lợi ích “chỉ tham chiếu một lần” mà mình đã nhắc trước đó. Vì bạn sử dụng các toán tử (< hoặc >), bạn phải lặp lại tham chiếu cho mỗi kiểm tra logic, tương tự như trong công thức IFS.

Tuy nhiên, việc linh hoạt quy tắc này là chấp nhận được vì bạn đang đổi một chút lặp lại để lấy tổ chức tối ưu. Ngay cả khi có tham chiếu lặp, cấu trúc SWITCH vẫn giữ logic của bạn trong một danh sách tuyến tính nghiêm ngặt. Điều này có nghĩa bạn không phải săn lùng dấu ngoặc đóng hoặc tự hỏi mình đang ở tầng lồng nào.

Hơn nữa, bạn vẫn hưởng lợi từ đối số “else” cuối cùng – một mạng an toàn mà IFS không có.

5. Chọn hàm phù hợp

Dù SWITCH rất tuyệt để dọn dẹp logic, nó không phải là cây đũa thần cho mọi tình huống. Có những lúc công thức lồng nhau hoặc IFS phức tạp lại là lựa chọn hợp lý hơn: